*MAX5941A TEST SETUP

.INCLUDE MAX5941.FAM
XTEST V+ VDD OPTO SS RCL GATE VEE OUT PG PGB GND CS V- ND VCC MAX5941A

*HOT SWAP INTERFACE
V_V+ GND V+ 0V
V_V- V- OUT 0V 
VSUP1 V+ VEE PULSE(0 40 0.5M 5M 1M 50M 100M)
CGATE OUT GATE 470P
RRCL RCL VEE 255
RDISC V+ VEE 25.5K
VPGB V5B VEE 5V
RPGB PGB V5B 100K
VPG V5 OUT 5V
RPG V5 PG 100K

*VDD INPUT GENERATED FROM OUTPUT 
ESUP2 VDD V- BST_OUT V+ 1
VG V- 0 0V

CREG VCC 0 10U
*SOFT START
CSS SS V- 5N

*BUCK-BOOST APPLICATION
CIN V+ V- 10U
LIN V+ BST1 4.7U
RLIN BST1 BST 30M
DOUT BST BST_OUT DA
COUT OUT1 V+ 10U
RESR BST_OUT OUT1 30M 
CBST BST V- 100P

MSW BST NDR CS CS MN1 L=1U W=4M
CGS NDR V- 1N
CGD BST V- 30P
RND NDR ND 1
RCS CS V- 0.12

RL BST_OUT V+ 20

*ERROR AMP(AV=100,POLE=98HZ,ZERO=700HZ)
R1 BST_OUT FB 210K
R2 FB 0 10K
VREF VR 0 2.5V
GEA 0 OPTO VR FB 1M
REA1 OPTO 0 100K
CEA1 OPTO OPTO1 14N
RZ1 OPTO1 0 16K
VLIM VL 0 4.5V
DEA1 0 OPTO DA
DEA2 OPTO VL DA

.MODEL MN1 NMOS(VTO=3.7 KP=100E-5)
.MODEL DA D(IS=100E-14 N=50M)
.TRAN 1U 10M 0 10U 
.PROBE
.END