* PSpice Model Editor - Version 10.0.0

*$
* MAX4335 MACROMODEL
* ------------------------------
* Revision 0, 11/2003
* ------------------------------
* MAX4435 opamp has rail-to-rail I/O and can deliver 40mW into 32ohm from 
* ultra-small packages making them ideal for mono/stereo headphone 
* drivers in portable applications. It has a 5MHz gain-bandwidth product and 
* can deliver 50mA of output current while operating from a single
* supply of 2.7V to 5.5V.  
* ------------------------------
* Connections
*      1  = IN+
*      2  = GND
*      3  = IN-
*      4  = OUT 
*      5  = N.C.
*      6  = VCC
*****************
.SUBCKT MAX4335 1 2 3 4 6
*INPUT STAGE
****************
RQ 6 2 2.284K
****************
CIN 3 1 5P
****************
VOS 99 1 0.6M
****************
IEE 6 7 18U
RE1 7 40 307.587
RE2 7 50 307.587
C1 20 30 1.82P
Q1 20 3 40 QX
Q2 30 99 50 QY
RC1 20 2 3.183K
RC2 30 2 3.183K
****************
*INTERMEDIATE STAGE
*POWER SUPPLY REJECTION ZERO AND POLE
GPS 21 22 6 2 98.303U
RPS1 22 23 10.101
RPS2 23 21 1K
LPS 23 21 79.57U

GPS2 21 220 22 21 99M
RPS12 220 230 10.101
RPS22 230 21 1K
LPS2 230 21 79.57U

*GAIN STAGES
GPSA 21 31 220 21 10U
GCMA 21 31 7 2 31.417N
GA 31 21 20 30 0.314M
R2 31 21 100K
C2 31 33 9.35P
E1 33 21 32 21 1
GB 32 21 31 21 0.636
RO2 32 21 199.105
****************
*LEVEL SHIFTING STAGE
ELEV1 76 2 6 2 1
RLEV 76 77 1MEG
CLEV 77 2 15.9U
ELEV2 21 2 77 2 0.5
****************
*OUTPUT CLAMPING
EOHO 66 0 6 0 1
VOHO 66 11 220M
D9 32 11 DX
D10 12 32 DX
VOLO 12 2 280M
****************
EBUFF 88 2 32 2 1
****************
*CURRENT LIMITING STAGE
D5 88 9 DX
D6 4 9 DX
D7 10 88 DX
D8 10 4 DX 
ILIMIT 9 10 110M
****************
*MODELS USED
.MODEL QX PNP(BF=86.957)
.MODEL QY PNP(BF=93.264)
.MODEL DX D(N=0.002 CJO=1E-18)
****************
.ENDS  

*$