* PSpice Model Editor - Version 10.0.0

*$
* MAX4294 MACROMODEL
* ------------------------------
* Revision 0, 1/2004
* ------------------------------
* MAX4294 quad operational amplifier has rail-to-rail outputs with 
* precision specifications and low-power consumption. 
* These amplifiers operate with a single-supply  voltage from 
* 1.8V to 5.5V, quiescent current of only 100uA and have
* a gain-bandwidth product of 500kHz.
* ------------------------------
* Connections
*      1  = OUTA
*      2  = INA-
*      3  = INA+
*      4  = VCC
*      5  = INB+
*      6  = INB-
*      7  = OUTB
*      8  = OUTC
*      9  = INC-
*     10  = INC+
*     11  = VEE
*     12  = IND+
*     13  = IND-
*     14  = OUTD
*****************
.SUBCKT MAX4294AMP 1 2 3 4 5
*INPUT STAGE
****************
IQ 5 2 98.2U
****************
*INPUT PROTECTION
RIN1 1 100 10.6K
RIN2 3 101 10.6K
DIN1 100 102 DY
DIN2 102 103 DY
DIN3 103 101 DY
DIN4 101 104 DY
DIN5 104 105 DY
DIN6 105 100 DY
****************
VOS 99 100 200U
****************
IEE 5 6 1.8U
RE1 6 40 4.897K
RE2 6 50 4.897K
C1 20 30 2.331P
Q1 20 101 40 QX
Q2 30 99 50 QY
RC1 20 2 30.83K
RC2 30 2 30.83K
****************
*INTERMEDIATE STAGE
*GAIN STAGES
GPSA 21 31 5 2 382.2P
GCMA 21 31 6 2 1.209N
GA 31 21 20 30 38.22U
R2 31 21 82.2K
C2 31 33 10P
EZ 33 21 32 21 1
GB 32 21 31 21 318.269
RO2 32 21 1K
****************
*LEVEL SHIFTING STAGE
VREF 21 2 0
****************
*OUTPUT CLAMPING
EVCC 555 0 5 0 1
HOHO 555 45 VILOAD 9.701 
VOHO 45 11 3.733M
D9 32 11 DX
D10 12 32 DX
VOLO 12 122 26.568M
HOLO 122 222 VILOAD -15.852
EVEE 222 0 2 0 1
****************
EBUFF 88 2 32 2 1
****************
*CURRENT LIMITING STAGE
D5 88 9 DX
D6 44 9 DX
D7 10 88 DX
D8 10 44 DX 
ILIMIT 9 10 20M
VILOAD 44 4 0
****************
*MODELS USED
.MODEL QX PNP(BF=57.5)
.MODEL QY PNP(BF=60.7)
.MODEL DX D(N=0.002 CJO=1E-18)
.MODEL DY D(N=0.6 CJO=1E-18)
****************
.ENDS  


*$