* PSpice Model Editor - Version 10.0.0

*$
* MAX4266 MACROMODEL
* ------------------------------
* Revision 0, 6/2004
* ------------------------------
* MAX4266 Op Amps are capable of driving 100ohms load while
* maintaining low distortion and wide bandwidth. These amplifiers 
* operate with a single-supply  voltage from +4.5V to +8V or from 
* dual +- 2.25V to +- 4V and are stable at gain of two.
* ------------------------------
* Connections
*      1  = DISABLE_
*      2  = IN-
*      3  = IN+
*      4  = VEE 
*      5  = VEE
*      6  = OUT
*      7  = VCC
*      8  = VCC
*****************
.SUBCKT MAX4266 1 2 3 4 5 6 7 8
*INPUT STAGE
****************
IQ 7 4 1.598M
GQ 7 4 109 0 26.4M
****************
VOS 3 100 1M
****************
*ICMR
RLIMIT 9 15 1
DICH 15 16 DX
VICH 7 16 0.63  
DICL 17 15 DX
VICL 17 4 2.5

GEED 5 8 109 0 10.007M
IEE 8 9 2U
GEE 8 9 109 0 10.005M
RE1 9 40 26.97
RE2 9 50 26.97
C1 20 30 2.887P
Q1 20 100 40 QX
Q2 30 2 50 QY
RC1 20 5 32.15
RC2 30 5 32.15
****************
*INTERMEDIATE STAGE
*GAIN STAGES
GPSA 31 21 7 0 1.749U
GCMA 31 21 9 4 1.749U
GA 21 31 20 30 31.11M
R2 21 31 100K
C2 31 33 10P
E1 33 21 32 21 1
GB 21 32 31 21 9.19M
RO2 21 32 1.968K
****************
*LEVEL SHIFTING STAGE
VREF 21 4 2.5
****************
*OUTPUT CLAMPING
VOHO 7 11 1.1
D9 32 11 DX
D10 12 32 DX
VOLO 12 4 1.1
****************
EBUFF 88 4 32 4 1
****************
*CURRENT LIMITING STAGE
D5 88 90 DX
D6 6 90 DX
D7 105 88 DX
D8 105 6 DX 
GLIMIT 90 105 109 0 99.9998M
ILIMIT 90 105 0.2U
****************
*SHUTDOWN
ESHDNH 106 107 7 0 1
VSHDNH 0 107 1.5
ESHDNL 108 110 8 0 1
VSHDNL 0 110 3.5
DSHDNH 111 106 DX
DSHDNL 108 111 DX
RSC 111 112 1
VIMEAS 112 1 0
FDIS 109 0 VIMEAS 1
DL 0 109 DX
DH 109 113 DX
VCLAMP 113 0 1
RPU 109 114 1MEG
VPU 114 0 0.5
****************
*MODELS USED
.MODEL QX PNP(BF=1408.451)
.MODEL QY PNP(BF=1449.275)
.MODEL DX D(N=0.002 CJO=1E-18)
.MODEL DY D(N=1E-6 CJO=1E-18)
****************
.ENDS
*$