*$
* MAX4027 MACROMODEL
* ------------------------------
* Revision 0, 12/2004
* ------------------------------
* MAX4027 is a triple, wideband, 2-channel, non-inverting
* gain-of-two video amplifier with input multiplexing.
* ------------------------------
* Connections
*      1  = IN1A
*      2  = IN2A
*      3  = IN3A
*      4  = GND 
*      5  = IN1B
*      6  = IN2B
*      7  = IN3B
*      8  = EN_
*      9  = OUT3
*     10  = VEE
*     11  = OUT2
*     12  = VCC
*     13  = OUT1
*     14  = A_\B
***************************************
.SUBCKT MAX4027 1 2 3 4 5 6 7 8 9 10
+               11 12 13 14
X1 8 10 4 13 12 1 5 14 15 MAX4027AMP
X2 8 10 4 11 12 2 6 14 15 MAX4027AMP
X3 8 10 4 9 12 3 7 14 15 MAX4027AMP
*SUPPLY CURRENTS
GQCC 4 12 15 4 25.18M
IQCC 12 4 56.18M
GQEE 4 10 15 4 13M
IQEE 4 10 15.01M 
.ENDS
***************************************

***************************************
.SUBCKT MAX4027AMP 1 4 5 6 7 8 9 10 109
*FEEDBACK
RF 6 3 0.8K
RIN 3 5 0.8K
*****************
SINA 8 5 10 5 SMOD4
SINB 9 5 10 5 SMOD5
CINA 8 5 2P
CINB 9 5 2P
EINA 313 5 8 5 1
EINB 314 5 9 5 1
*****************
*2:1 INPUT MUX
S2 313 2 10 5 SMOD2
S3 314 2 10 5 SMOD1
*****************
*INPUT STAGE
****************
IEER 4 7 5.19M
****************
IEE 7 99 5.19M
RE1 99 40 70.714
RE2 99 50 70.714
Q1 20 3 40 QX
Q2 30 223 50 QY
VOS 2 223 0.2M
RC1 20 4 70.726
RC2 30 4 70.726
****************
*INTERMEDIATE STAGE
*POWER SUPPLY REJECTION
GPSCC 21 22 7 5 28.86M
RPSCC 21 22 1
GPSEE 21 222 4 5 28.86M
RPSEE 21 222 1
*GAIN STAGES
GPSACC 31 21 22 21 10U
GPSAEE 31 21 222 21 10U
GA 31 21 20 30 13.2M
R2 31 21 100K
C2 31 33 4.68P
E1 33 21 55 21 1
GB 21 55 31 21 15.73M
RO2 21 55 500
****************
*LEVEL SHIFTING STAGE
VREF 21 5 0
****************
*OUTPUT CLAMPING
VOHO 56 7 1.5
D9 55 56 DX
D10 57 55 DX
VOLO 57 4 1.5
****************
EBUFF 58 5 55 5 1
****************
*CURRENT LIMITING STAGE
D5 58 59 DX
D6 60 59 DX
D7 61 58 DX
D8 61 60 DX 
ILIMIT 59 61 143M
****************
*OUTPUT ENABLE
S1 60 6 1 5 SMOD3
****************
*DISABLE LOGIC
VSHDNH 107 5 1
SDIS 107 109 1 5 SMOD2
RSC 109 5 100
****************
*MODELS USED
.MODEL QX PNP(BF=1297.5)
.MODEL QY PNP(BF=1297.5)
.MODEL DX D(N=0.002 CJO=1E-18)
.MODEL SMOD1 VSWITCH(RON=0.001 ROFF=100MEG VON=2 VOFF=0.8)
.MODEL SMOD2 VSWITCH(RON=0.001 ROFF=100MEG VON=0.8 VOFF=2)
.MODEL SMOD3 VSWITCH(RON=0.001 ROFF=100G VON=0.8 VOFF=2)
.MODEL SMOD4 VSWITCH(RON=400K ROFF=20MEG VON=0.8 VOFF=2)
.MODEL SMOD5 VSWITCH(RON=400K ROFF=20MEG VON=2 VOFF=0.8)
****************
.ENDS
***************************************
*$