* MAX4413 MACROMODEL
* ------------------------------
* Revision 0, 10/2003
* ------------------------------
* MAX4413 is a low-cost, low-power, ultra-small dual opamp operating
* from a single +2.7V to +5.5V supply and have rail to rail outputs.
* It achieves a 500MHz -3dB bandwidth and a 220V/us slew-rate while consuming 
* only 1.7mA of supply current per amplifier.  
* ------------------------------
* Connections
*      1  = OUTA
*      2  = INA-
*      3  = INA+
*      4  = VEE
*      5  = INB+
*      6  = INB-
*      7  = OUTB
*      8  = VCC
********************************
.SUBCKT MAX4413 1 2 3 4 5 6 7 8
XAMP1 3 4 2 1 8 MAX4413AMP
XAMP2 5 4 6 7 8 MAX4413AMP
.ENDS
********************************

****************
.SUBCKT MAX4413AMP 1 2 3 4 5
*INPUT STAGE
****************
RQ 5 2 8.333K
****************
CIN 3 1 1.8P
****************
VOS 99 1 0.4M
****************
IEE 5 6 1.103M
RE1 6 40 49.85
RE2 6 50 49.85
C1 20 30 1.9P
Q1 20 3 40 QX
Q2 30 99 50 QY
RC1 20 2 96.886
RC2 30 2 96.886
****************
*INTERMEDIATE STAGE
*POWER SUPPLY REJECTION ZERO AND POLE
GPS 21 22 5 2 9.559M
RPS1 22 23 16.95
RPS2 23 21 1K
LPS 23 21 2.652U

*COMMON MODE REJECTION ZERO AND POLE
GCM 21 24 6 2 2.268M
RCM1 24 25 10.09
RCM2 25 21 1K
LCM 25 21 1.59U

*GAIN STAGES
GPSA 21 31 22 21 10U
GCMA 21 31 24 21 10U
GA 31 21 20 30 11.47M
R2 31 21 100K
C2 31 33 4.5P
E1 33 21 32 21 1
GB 32 21 31 21 0.279M
RO2 32 21 31.268K
****************
*LEVEL SHIFTING STAGE
ELEV1 21 51 5 0 0.5 
ELEV2 52 2 5 2 -0.5
CLEV 52 51 1E9
RLEV 51 2 1
****************
*OUTPUT CLAMPING
VOHO 5 11 105M
D9 32 11 DX
D10 12 32 DX
VOLO 12 2 35M
****************
EBUFF 88 2 32 2 1
****************
*CURRENT LIMITING STAGE
D5 88 9 DX
D6 4 9 DX
D7 10 88 DX
D8 10 4 DX 
ILIMIT 9 10 85M
****************
*MODELS USED
.MODEL QX PNP(BF=333.333)
.MODEL QY PNP(BF=354.839)
.MODEL DX D(N=1M)
****************
.ENDS  
*****************