* MAX4402 MACROMODEL
* ------------------------------
* Revision 0, 03/2005
* ------------------------------
* MAX4402 general purpose opamp offer rail to rail outputs, draws
* only 320uA of quiescent current, and operate from a single +2.5V
* to +5.5V supply. It also has shutdown capability reducing supply 
* current to 1uA. This device is unity-gain stable with a 800kHz 
* gain-bandwidth product.  
* ------------------------------
* Connections
*      1  = OUTA
*      2  = INA-
*      3  = INA+
*      4  = VSS
*      5  = INB+
*      6  = INB-
*      7  = OUTB
*      8  = VDD
*****************
.SUBCKT MAX4402 1 2 3 4 5 6 7 8
X1 3 4 2 1 8 MAX4402AMP
X2 5 4 6 7 8 MAX4402AMP
.ENDS
*****************

*****************
.SUBCKT MAX4402AMP 1 2 3 4 6
*INPUT STAGE
IQSHDN 2 6 390P
GQ1 6 2 POLY(2) 6 2 78 2 0 0 0 0 36U
GQ2 6 2 78 2 220U
****************
VOS 99 1 1.0M
****************
CIN 1 3 2.5P
****************
*ICMR
DICMRL 82 7 DX
VICMRL 82 2 0.7
****************
GSS 6 7 78 2 10U
RE1 7 40 13.618K
RE2 7 50 13.618K
C1 20 30 1.82P
Q1 20 3 40 QX
Q2 30 99 50 QY
RC1 20 2 18.789K
RC2 30 2 18.789K
****************
*INTERMEDIATE STAGE
*POWER SUPPLY REJECTION ZERO AND POLE
GPS 21 22 6 2 1
RPS1 22 23 1
LPS 23 21 2M
*GAIN STAGES
GPSA 21 31 22 21 0.532N
GCMA 21 31 7 2 3.358N
GA 31 21 20 30 53.225U
R2 31 21 100K
C2 31 33 10P
E1 33 21 32 21 1
GB 32 21 31 21 23.485
RO2 32 21 8K
****************
*LEVEL SHIFTING STAGE
VLEV 21 2 2.5
****************
*OUTPUT CLAMPING
EOHO 68 0 6 2 1 
VOHO 68 11 3M
D9 32 11 DX
D10 12 32 DX
VOLO 12 2 2M
****************
VBUFF 88 32 0
****************
*CURRENT LIMITING STAGE
D5 88 9 DX
D6 4 9 DX
D7 10 88 DX
D8 10 4 DX 
GLIMIT1 9 10 78 2 12.034M
GLIMIT2 9 10 POLY(2) 83 2 78 2 0 0 0 0 17.93M 
ILSHDN 9 10 1U
FSINK 2 83 VBUFF 1
DSINK1 83 84 DX
VSINK 84 2 1
DSINK2 2 83 DX
****************
*SHUTDOWN STAGE
ESHDN 79 2 VALUE={V(5,2)/V(6,2)}
ILEAK 5 2 1P
VSHDN 77 2 1
SSHDN 77 78 79 2 SMOD
RSHDN 78 2 1K
*SHUTDOWN DISABLED
ESHDIS 5 2 6 2 1
****************
*MODELS USED
.MODEL QX PNP(BF=3.333E7)
.MODEL QY PNP(BF=1E8)
.MODEL DX D(N=2M IS=1E-18 CJO=1E-18)
.MODEL SMOD VSWITCH(RON=0.01 ROFF=1E9 VON=0.7 VOFF=0.3)
****************
.ENDS