* MAX4462H MACROMODEL
* ------------------------------
* Revision 0, 12/2003
* ------------------------------
* MAX4462H instrumentation amplifier has rail-to-rail outputs with 
* precision specifications, low-power consumption, and excellent 
* gain-bandwidth product. MAX4462H is offered in fixed gain of 100 and has 
* a reference input pin. These amplifiers operate with a single-supply
* voltage from 2.85V to 5.25V, quiescent current of only 700uA and have
* a gain-bandwidth product of 2.5MHz.
* ------------------------------
* Connections
*      1  = OUT
*      2  = VSS
*      3  = IN+
*      4  = IN- 
*      5  = VDD
*      6  = REF
*****************
.SUBCKT MAX4462H 1 2 3 4 5 6
*INPUT STAGE
****************
RQ 5 2 6.667K
****************
VOS 99 3 100U
****************
*INPUT BIAS CURRENT
RBIAS1 7 4 2E12
RBIAS2 7 99 2E12
****************
*ICMR
VOFF 7 47 2
DCMRH 47 45 DX
VCMRH 5 45 1.7
DCMRL 46 47 DX
VCMRL 2 46 0.1
****************
ISS 5 7 50U
RS1 7 40 19.859K
RS2 7 50 19.859K
M1 20 4 40 40 PMOS W=100U L=100U
M2 30 99 50 50 PMOS W=100U L=100U
RD1 20 2 20K
RD2 30 2 20K
****************
*DIFFERENTIAL INPUT RESISTANCE
RIND 4 99 2E9
****************
*INTERMEDIATE STAGE
*POWER SUPPLY REJECTION ZERO AND POLE
GPS 21 22 5 2 9.546U
RPS1 22 23 33.34M
RPS2 23 21 1K
LPS 23 21 53.05U

*COMMON MODE REJECTION ZERO AND POLE
GCM 21 24 7 2 47.72N
RCM1 24 25 0.667
RCM2 25 21 1K
LCM 25 21 53.05U

*GAIN STAGES
GPSA 21 31 22 21 15.71U
GCMA 21 31 24 21 15.71U
GA 31 21 20 30 50U
R2 31 21 63.654K
C2 21 31 100P
GB 32 21 31 21 31.42
RO2 32 21 1
****************
*REFERENCE STAGE
EREF 21 2 6 2 1
****************
*OUTPUT CLAMPING
EOHO 66 0 5 0 1
VOHO 66 11 3M
D9 32 11 DX
D10 12 32 DX
VOLO 12 2 4M
****************
EBUFF 88 2 32 2 1
****************
*CURRENT LIMITING STAGE
D5 88 9 DX
D6 1 9 DX
D7 10 88 DX
D8 10 1 DX 
ILIMIT 9 10 150M
****************
*MODELS USED
.MODEL PMOS PMOS(KP=1 VTO=-1.5)
.MODEL DX D(N=0.002 CJO=1E-18)
****************
.ENDS  
****************