* MAX4461U MACROMODEL
* ------------------------------
* Revision 0, 12/2003
* ------------------------------
* MAX4461U instrumentation amplifier has rail-to-rail outputs with 
* precision specifications, low-power consumption, and excellent 
* gain-bandwidth product. MAX4461U is offered in fixed gain of 1 and has 
* a logic-controlled shutdown input. These amplifiers operate with a single-supply
* voltage from 2.85V to 5.25V, quiescent current of only 700uA and have
* a gain-bandwidth product of 2.5MHz.
* ------------------------------
* Connections
*      1  = OUT
*      2  = GND
*      3  = IN+
*      4  = IN- 
*      5  = VDD
*      6  = SHDN_
*****************
.SUBCKT MAX4461U 1 2 3 4 5 6
*INPUT STAGE
*SHUT-DOWN
GDN1 101 100 6 2 1
RDN1 100 101 1
EDN1 101 2 5 2 -0.3
DDN1 100 102 DY
EDN2 102 2 5 2 0.4
DDN2 2 100 DY
GDN2 103 77 100 2 2.5
RDN2 77 103 1
EDN3 103 104 5 2 -1
VDN1 104 2 1
DDN3 77 105 DY
VDN2 105 2 1
DDN4 2 77 DY
MSHDN 5 77 68 68 NMOS W=100U L=100U
****************
RQ 68 2 1.2K 
****************
VOS 99 3 100U
****************
*INPUT BIAS CURRENT
RBIAS1 7 4 2E12
RBIAS2 7 99 2E12
****************
*ICMR
VOFF 7 47 2
DCMRH 47 45 DX
VCMRH 5 45 1.7
DCMRL 46 47 DX
VCMRL 2 46 0.1
****************
GSS 5 7 77 2 50U
ISSDN 5 7 0.1U  
RS1 7 40 19.859K
RS2 7 50 19.859K
M1 20 4 40 40 PMOS W=100U L=100U
M2 30 99 50 50 PMOS W=100U L=100U
RD1 20 2 20K
RD2 30 2 20K
****************
*DIFFERENTIAL INPUT RESISTANCE
RIND 4 99 2E9
****************
*INTERMEDIATE STAGE
*POWER SUPPLY REJECTION ZERO AND POLE
GPS 21 22 5 2 9.546U
RPS1 22 23 33.34M
RPS2 23 21 1K
LPS 23 21 53.05U

*COMMON MODE REJECTION ZERO AND POLE
GCM 21 24 7 2 47.72N
RCM1 24 25 0.667
RCM2 25 21 1K
LCM 25 21 53.05U

*GAIN STAGES
GPSA 21 31 22 21 1.571M
GCMA 21 31 24 21 1.571M
GA 31 21 20 30 50U
R2 31 21 636.54
C2 21 31 100P
GB 32 21 31 21 31.42
RO2 32 21 1
****************
*REFERENCE STAGE
VREF 21 2 0
****************
*OUTPUT CLAMPING
EOHO 66 0 5 0 1
VOHO 66 11 3M
D9 32 11 DX
D10 12 32 DX
VOLO 12 2 2M
****************
EBUFF 88 2 32 2 1
****************
*CURRENT LIMITING STAGE
D5 88 9 DX
D6 1 9 DX
D7 10 88 DX
D8 10 1 DX 
GLIMIT 9 10 77 2 150M
ISHDN 9 10 1N
****************
*MODELS USED
.MODEL PMOS PMOS(KP=1 VTO=-1.5)
.MODEL NMOS NMOS(LEVEL=1 KP=1 VTO=0.05)
.MODEL DX D(N=0.002 CJO=1E-18)
.MODEL DY D(N=1U CJO=1E-18)
****************
.ENDS  
****************