* MAX4372H MACROMODEL
* ------------------------------
* Revision 0, 2/2005
* ------------------------------
* The MAX4372 family of low cost, precision high side current sense amplifiers
* feature a voltage output that eliminates need for gain setting resistors and
* has an input common mode range of 0 to +28v which is independent of power 
* supply voltage.
* ------------------------------
* Connections
*      1  = GND
*      2  = OUT
*      3  = VCC
*      4  = RS+
*      5  = RS-
*****************************
.SUBCKT MAX4372H 1 2 3 4 5   
*****************
*INPUT STAGE
RIN 4 5 10MEG
GIN1 4 14 4 5 10U
D1 14 13 DB
D2 1 14 DB
RGD 13 1 100K
IOFF 1 13 0.003U  
GIN2 5 18 4 5 20U
*****************
GIN3 1 18 3 1 1M
RIN3 18 1 1K
DIN3 18 15 DA
VS2 15 1 2V
RIN1 18 16 80K
DIN1 16 4 DA
DIN2 17 4 DA
RIN2 18 17 40K
*****************
*OUTPUT AMP
GA3 1 19 13 23 1M
RA3 19 1 1K
DSL1 19 25 DA
DSL2 26 19 DA
VSL1 25 1 7.225M
VSL2 1 26 4.815M
GA1 20 1 19 1 1M
RA1 20 1 7.7K
GA2 21 1 20 1 8.651
RA2 21 1 115.6
EF 22 1 21 1 1
CC 20 22 14.45P
VOUT 21 2 0V
RF 22 23 9.9MEG
R1 23 1 100K
*****************
*OUTPUT LIMIT
VOL 28 29 0.1
ESUP 28 1 3 1 1
DO 21 29 DA
*INPUT LIMIT  
VIL 27 1 10V
DIL 21 27 DA
DI1 1 4 DA
DI2 1 5 DA 
*****************
*PSRR AC AND DC RESPONSE
GPSRR 1 13 3 1 28.12P
EPSRR 30 1 3 1 1
CPSRR 30 31 10P
RPSRR 31 1 50
CPSRR1 31 1 40N
GPSRR1 1 13 31 1 10u
*****************
*CMRR
GCMRR 1 13 4 1 28.12P
*****************
*SUPPLY CURRENT
ISUP 3 1 30U
**********************************************************
.MODEL DA D(N=0.1M) 
.MODEL DB D(IS=100E-14)
**********************************************************
.ENDS