* MAX4198 MACROMODEL
* ------------------------------
* Revision 0, 2/2004
* ------------------------------
* MAX4198 differential amplifier has rail-to-rail outputs with 
* precision specifications and low-power consumption. 
* These amplifiers operate with a single-supply  voltage from 
* +2.7V to +7.5V or from dual +- 1.35V to +- 3.75V, quiescent 
* current of only 45uA and have a gain-bandwidth product of 175kHz. 
* These amplifiers feature a shutdown mode that reduces the supply 
* current to 6.5uA.
* ------------------------------
* Connections
*      1  = REF
*      2  = IN-
*      3  = IN+
*      4  = VEE 
*      5  = FB
*      6  = OUT
*      7  = VCC
*      8  = SHDN_
*****************
.SUBCKT MAX4198 1 2 3 4 5 6 7 8
*INPUT STAGE
****************
GQ 7 4 POLY(2) 7 4 109 0 0 0 0 0 7.554E-6
IQ 7 4 6.5U
****************
VOS 100 3 30U
****************
GSS 7 9 109 0 0.732U
M1 20 101 9 9 PMOS(W=100U L=100U)
M2 30 99 9 9 PMOS(W=100U L=100U)
RD1 20 4 45.467K
RD2 30 4 45.467K
****************
*INTERMEDIATE STAGE
*COMMON MODE REJECTION ZERO 
GCM1 21 240 9 4 1M
RCM1 240 250 1K
LCM 250 21 0.2
*GAIN STAGES
GCMA 21 31 240 21 0.696N
GA 31 21 20 30 21.994U
R2 31 21 100K
C2 31 33 10P
EZ 33 21 32 21 1
GB 32 21 31 21 450
RO2 32 21 1K
****************
*LEVEL SHIFTING STAGE
VREF 21 4 0
****************
*OUTPUT CLAMPING
EVCC 555 0 7 0 1
HOHO 555 45 VILOAD 170
VOHO 45 11 0.84M
D9 32 11 DX
D10 12 32 DX
VOLO 12 122 -0.84M
HOLO 122 222 VILOAD -170
EVEE 222 0 4 0 1
****************
EBUFF 88 4 32 4 1
****************
*CURRENT LIMITING STAGE
D5 88 90 DX
D6 44 90 DX
D7 105 88 DX
D8 105 44 DX 
GLIMIT 90 105 109 0 5.5M
VILOAD 44 6 0
****************
*FEEDBACK
RINF 101 5 25K
RIN1 2 101 25K
RNINF 99 1 25K
RNIN 100 99 25K
****************
*SHUTDOWN
ESHDN1 106 107 8 0 1
VSHDN2 107 108 2.5
ESHDN2 0 108 7 0 1
GSHDN 0 109 106 0 1M
RSHDN 109 0 1K
DSHDN1 109 110 DY
VSHDN1 110 0 1
DSHDN2 0 109 DY 
****************
*MODELS USED
.MODEL PMOS PMOS(VTO=-0.5 KP=6.661E-4)
.MODEL DX D(N=0.002 CJO=1E-18)
.MODEL DY D(N=1E-6 CJO=1E-18)
****************
.ENDS