* PSpice Model Editor - Version 10.0.0

*$
* MAX9602 MACROMODEL
* ------------------------------
* Revision 0, 11/2003
* ------------------------------
* MAX9602 is a ultra-high-speed quad comparator with extremely low 
* propogation delay(500 ps). The outputs are complimentary digital 
* signals, compatible with PECL systems.
* ------------------------------
* Connections
*   1  = INA+
*   2  = INA-
*   3  = VEE
*   4  = INB+
*   5  = INB-
*   6  = VCC
*   7  = INC+
*   8  = INC-
*   9  = VEE
*  10  = IND+
*  11  = IND-
*  12  = VCC
*  13  = QD_
*  14  = QD
*  15  = VCCOD
*  16  = QC_
*  17  = QC
*  18  = VCCOC
*  19  = QB_
*  20  = QB
*  21  = VCCOB
*  22  = QA_
*  23  = QA
*  24  = VCCOA
*****************
* NOTE1: OUT_ IS ACTUALLY COMPLIMENTED OUT. 
* NOTE2: OUTPUT IS MEASURED WITH RESPECT TO VCC0
* NOTE3: INCLUDE 
*            .OPTIONS ITL4=50  
*                             TO ENHANCE CONVERGENCE.
*****************
.SUBCKT MAX9602CMP 1 2 3 4 5 6 7
*INPUT STAGE
****************
RPC 3 0 181.159
RPE 4 0 138.298
****************
CIN 2 5 2P
****************
VOS 99 1 1M
****************
IEE 3 11 400U
Q1 12 2 11 QX
Q2 13 99 11 QY
RC1 12 4 129.3
RC2 13 4 129.3
****************
*INTERMEDIATE STAGE
GA 5 14 12 13 1
RA 14 5 100K
CA 14 5 1E-18
D1 14 15 DX
VOH 15 5 -0.94
D2 16 14 DX
VOL 16 5 -1.72
**************
EOUT 19 5 14 5 1
**************
ECCL 33 5 15 5 1
EEEL 44 5 16 5 1
M1 21 19 33 33 PMOS 
M2 21 19 44 44 NMOS
**************
*DELAY,RISE AND FALL TIME
EDELQ 102 5 19 5 1
T1Q 102 5 17 5 ZO=50 TD=166P
RTERMQ 17 5 50 
CTERMQ 17 5 0.185P
GRISEQ 5 23 17 5 1M
RRISEQ 23 5 1K
C23 23 5 0.15P
****
EDELQB 103 5 21 5 1
T1QB 103 5 18 5 ZO=50 TD=166P
RTERMQB 18 5 50 
CTERMQB 18 5 0.185P
GRISEQB 5 24 18 5 1M
RRISEQB 24 5 1K
C24 24 5 0.15P
****************
E1 6 5 23 5 1
E2 7 5 24 5 1
****************
*MODELS USED
.MODEL QX PNP(BF=34.188)
.MODEL QY PNP(BF=32.52)
.MODEL DX D(N=0.001 TT=1E-15)
.MODEL NMOS NMOS(KP=1 TOX=100U VTO=0.39 W=1U L=1U)
.MODEL PMOS PMOS(KP=1 TOX=100U VTO=-0.39 W=1U L=1U)
****************
.ENDS  
*$