* MAX4543 MACROMODEL
* ------------------------------
* Revision 0, 6/2006
* ------------------------------
* MAX4543 is a low-voltage, low on-resistance, dual analog switch
* operating from a single +2.7V to +12V supply.
* ------------------------------
* Connections
*      1  = NO1
*      2  = V+
*      3  = IN2
*      4  = COM2
*      5  = NC2
*      6  = GND
*      7  = IN1
*      8  = COM1
*****************
.SUBCKT MAX4543 1 2 3 4 5 6 7 8
X1 2 6 1 8 7 MAX4543SPSTNO
X2 2 6 5 4 3 MAX4543SPSTNC
.ENDS
*****************

***************** 
.SUBCKT MAX4543SPSTNO 1 2 3 4 5
*POWER SUPPLY RANGE
DH 1 10 DSW
VH 10 2 12
DL 11 1 DSW
VL 11 2 2.7
*ANALOG SIGNAL RANGE
DNOH 3 1 DSW
DNOL 2 3 DSW
DCOMH 4 1 DSW
DCOML 2 4 DSW
*SUPPLY CURRENT
RSUP 1 2 110G 
*SPST SWITCH 
MPINV1 12 5 1 1 PMOS W=10U L=2U
MNINV1 12 5 2 2 NMOS W=15U L=2U
MPINV2 13 12 1 1 PMOS W=10U L=2U
MNINV2 13 12 2 2 NMOS W=10U L=2U
MNH 12 13 2 2 NMOS W=10.5U L=2U
MPINV3 6 13 1 1 PMOS W=10U L=2U
MNINV3 6 13 2 2 NMOS W=10U L=2U
MNNO 3 13 4 2 NMOS W=2.61U L=2U
MPNO 4 6 3 1 PMOS W=2.61U L=2U
CT 3 4 1.95P
.MODEL NMOS NMOS(VTO=0.6 KP=6.50E-3 IS=1F CBD=0P CBS=0P CGSO=1.245U CGDO=1.245U CGBO=0P)
.MODEL PMOS PMOS(VTO=-0.6 KP=6.50E-3 IS=1F CBD=0P CBS=0P CGSO=1.245U CGDO=1.245U CGBO=0P)
.MODEL DSW D(IS=1E-12 RS=5 BV=6 CJO=1E-15)
.ENDS
*****************

***************** 
.SUBCKT MAX4543SPSTNC 1 2 3 4 5
*POWER SUPPLY RANGE
DH 1 10 DSW
VH 10 2 12
DL 11 1 DSW
VL 11 2 2.7
*ANALOG SIGNAL RANGE
DNOH 3 1 DSW
DNOL 2 3 DSW
DCOMH 4 1 DSW
DCOML 2 4 DSW
*SUPPLY CURRENT
RSUP 1 2 110G 
*SPST SWITCH 
MPINV1 12 5 1 1 PMOS W=10U L=2U
MNINV1 12 5 2 2 NMOS W=15U L=2U
MPINV2 13 12 1 1 PMOS W=10U L=2U
MNINV2 13 12 2 2 NMOS W=10U L=2U
MNH 12 13 2 2 NMOS W=10.5U L=2U
MPINV3 6 13 1 1 PMOS W=10U L=2U
MNINV3 6 13 2 2 NMOS W=10U L=2U
MNNO 3 6 4 2 NMOS W=2.61U L=2U
MPNO 4 13 3 1 PMOS W=2.61U L=2U
CT 3 4 1.95P
.MODEL NMOS NMOS(VTO=0.6 KP=6.50E-3 IS=1F CBD=0P CBS=0P CGSO=1.245U CGDO=1.245U CGBO=0P)
.MODEL PMOS PMOS(VTO=-0.6 KP=6.50E-3 IS=1F CBD=0P CBS=0P CGSO=1.245U CGDO=1.245U CGBO=0P)
.MODEL DSW D(IS=1E-12 RS=5 BV=6 CJO=1E-15)
.ENDS
*****************